Флешка, считывающая названия картинок в папке

<?
$dir = opendir ("images"); // открыть папку images для чтения
  
while ( $file = readdir ($dir)) // перебор всех файлов  папке
// следует учесть, что при переборе файлов в конце обязательно будет
// две строки - "." и "..". Дл того, чтобы не передавать их во флешку, ставим условие
if (( $file != ".") && ($file != ".."))
  echo "$file "; // возвращаем имя файла ($file) и пробел (!) в конце

closedir ($dir); // закрываем открытую папку
?>

// импорт необходимых для работы классов
import flash.display.BitmapData;
import flash.display.*;
import flash.geom.*;

//остановим проигрывание до загрузки всех картинок
stop();
//////////// иициализация переменных: \\\\\\\\\\\\\\\\\\
dir = 'images/'; // путь к папке, в которой находятся картинки
loaded = 0; // счётчик загруженых картинок
bitmapdatas = []; // массив для хранения BitmapData - "снимков" клипов с картинками

// создадим метод toBitmap(), который будет вызываться после каждой загрузке картинки с сервера.
// Как аргумент функция принимает ссылку на мувиклип, в котором завершилась загрузка картинки.
// Эта функция будет делать "снимок" клипа с картинкой при помощи класса BitmapData
// а также проверять, все ли картинки уже загрузились
function toBitmap(img_mc) {
// создаём новый экземпляр класса BitmapData, шириной и высотой как сцена flash ролика
    _root['bitmap'+loaded] = new BitmapData(Stage.width, Stage.height, true, 0);
// при помощи метода BitmapData.draw() делаем снимок клипа
    _root['bitmap'+loaded].draw(img_mc);
// заносим в наш массив для хранения этих данных
    bitmapdatas[loaded] = _root['bitmap'+loaded];
// т.к. загрузилась ещё одна картинка, наращиваем счётчик загруженых картинок
    loaded++;

// проверяем, все картинки уже загрузились, если да -
// то переходим на второй кадр, где располагается галерея
    if (loaded == images.length) {
        _root.gotoAndStop(2);
    }
}



// после того, как с сервера будет получена строка с содержимым папки и разобрана в массив,
// мы перемешаем его. Удобную и лаконичную функцию я когда-то давно нашёл на flasher.ru
// данна фунция принимает на вход массив (тип данных в нём может быть любой)
// и возвращает его назад с элементами, расставлеными в случайном порядке
function Shuffle(x) {
    var tmp = x.concat();
    var new_x = new Array();
    while (tmp.length>0) {
        var rnd = random(tmp.length);
        new_x.push(tmp.splice(rnd, 1));
    }
    return new_x;
}


// Для того, чтобы обратиться к php скрипту за списком имён файлов в папке,
// создадим два экземпляра класса LoadVars,
// один для отсылки запросы на php скрипт, второй - для получения ответа
var sender:LoadVars = new LoadVars(); // Отправитель
var receiver:LoadVars = new LoadVars();// Получатель

sender.sendAndLoad("script.php", receiver, "POST");// выполняем запрос

// Функция-обработчик поступления данных во флешку
receiver.onData = function(text):Void  {
    
    images = []; // инициализация массива для хранения ссылок на картинки
    // в переменной text хранятся данные, которые возвратил скрипт.
    // В самом начале ответа сервера находится символ переноса строки,
//следующей строкой убираем его:
    text = text.split('\n')[1];
    /* Так как серверный php скрипт отдаёт нам имена файлов,
    разделяя их пробелом, опять воспользуемся методом split()
    для разбивки строки на массив */
    
    images = text.split(' ');// получаем массив со ссылками на картинки

    /* В самом конце списка картинок на сервере находится пробел, поэтому в нашем массиве
    со ссылками на картинки последний элемент является лишним.
    Для того, чтобы убрать последний элемент массива, достаточно просто переопределить
    его свойство length, сделав его меньше на 1*/
    images.length = images.length-1;
    
    //Для перемешивания массива воспользуемся функцией Shuffle()
    images = Shuffle(images); // получим массив ссылок на картинки для галереи в случайном порядке
    
    // в цикле перебираем все элементы массива со ссылками
    for (i=0; i<images.length; i++) {
// Для каждого создаём свой клип-контейнер
// Важно не забывать, что имена и глубины каждого клипа должны быть уникальны, поэтому
// для формирования имени и глубины используем счётчик цикла - переменную i
        mc = _root.createEmptyMovieClip("mc"+i, i);
// чтобы при загрузке перед пользователем не мелькали картинки,
// нужно как-то скрывать клипы-контейнеры, в которые грузятся картинки.
// Простейший способ - переместить клип за границы клипа, поставим координату по оси x равной 3000
        mc._x = 3000;

// Для загрузки картинок в клипы создадим экземпляры класса MovieClipLoader
        _root['mcl'+i] = new MovieClipLoader();
// А также обьекты-слушатели для отслеживания окончания загрузки картинок
        _root['listener'+i] = {};
// Присоединяем листенеры к MovieClipLoader`ам
        _root['mcl'+i].addListener(_root['listener'+i]);
// начинаме загрузку
        _root['mcl'+i].loadClip(dir+images[i], _root['mc'+i]);
// в каждом обьекте-слушателе создаём свйство mc,
// которое хранит ссылку на клип, к которому он относится
        _root['listener'+i].mc = mc;
// при завершении загрузки картинки будет вызываться данный метод
        _root['listener'+i].onLoadInit = function() {
// После окончания загрузки картинки в клип вызываем функцию toBitmap(),
// передавая ссылку на клип
            toBitmap(this.mc);
// после этого удаляем клип - он нам больше пригодится,
// ведь после выполнения функции toBitmap() у нас есть его содержимое
            this.mc.removeMovieClip();
        };
    }
};

total = bitmapdatas.length; // всего картинок в галерее
n = 0; // просто счётчик, для уникальности создаваемых клипов и глубин

function getNextPic() { // при вызове этой функции буду сменяться картинки
    old = mc; // запоминаем ссылку на старый клип, который нужно будет удалить
    mc = _root.createEmptyMovieClip('pic'+n, _root.getNextHighestDepth()); // создаём новый клип с униакальным именем, помещаем на самый высший уровень плеера
    mc.attachBitmap(bitmapdatas[n], 0, "auto", true); // "вкладываем" в него картинку
    mc._alpha = 0; // ставим прозрачнсть на ноль (т.е. делаем клип с картинкой полностью прозрачным)
    mc.onEnterFrame = function() { // функция, которая будет выполняться в клипе при каждойсмене кадров
        this._alpha += 10; // увеличиваем прозрачность клипа на 10 %
        // проверка условия:
        if (this._alpha==100) { // ели прозрачность клипа 100%
        old.removeMovieClip(); // то удаляем клип, который находится под ним (т.к. он нам больше не нужен)
        delete this.onEnterFrame; // удаляем фунцию
        }
        
    }

// для того, чтобы флешка не пыталась грузить картинки,
//которых не существует, делаем следующую проверку:
    if (n==total-1) { // достиг ли наш счётчик максимума
        n = 0; // ели достиг, то обнуляем его
    } else {
        n++; // если нет - наращиваем счётчик на единицу (инкремент)
    }
}


// для того, чтобы пользователю не пришлось ждать смены картинок
// перед загрузкой первой картинки,
// сразу же вызываем функцию getNextPic(), которая покажет первую картинку сразу при загрузке
getNextPic();
// а также устанавливаем интервал, с которым должна вызываться данная фнкция в дальнейшем.
// Дклаем это при помощи метода setInterval(). Первый параметр - имя функции,
//второй - время интервала в миллисекундах, то есть 1500 - 1,5 секунды
setInterval(getNextPic, 1500);